SPARQL Queryのサンプル

川越市のコード及び改正履歴を調べる

川越市のコード及び改正履歴を取得するクエリーです

PREFIX rdfs:<http://www.w3.org/2000/01/rdf-schema#>
PREFIX org:<http://www.w3.org/ns/org#>
PREFIX dcterms:<http://purl.org/dc/terms/>
select *
where {
      ?s rdfs:label "川越市"@ja ;
         org:resultedFrom / dcterms:description ?rfc .
      FILTER(LANG(?rfc)='ja')
}
ORDER BY DESC(?s)

 

新宿区の日本人の人口を求める

新宿区の日本人の人口を求めるクエリーです

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX estat-measure: <http://data.e-stat.go.jp/lod/ontology/measure/>
PREFIX cd-dimension: <http://data.e-stat.go.jp/lod/ontology/crossDomain/dimension/>
PREFIX cd-code: <http://data.e-stat.go.jp/lod/ontology/crossDomain/code/>
PREFIX g00200521-dimension-2010:<http://data.e-stat.go.jp/lod/ontology/g00200521/dimension/2010/>
PREFIX g00200521-code-2010:<http://data.e-stat.go.jp/lod/ontology/g00200521/code/2010/>
select  ?year ?population
where {
      ?s estat-measure:population ?population ;
         sdmx-dimension:refArea / rdfs:label "新宿区"@ja ;
         cd-dimension:timePeriod ?year ;
         cd-dimension:sex cd-code:sex-all ;
         cd-dimension:nationality cd-code:nationality-japan ;
         g00200521-dimension-2010:area g00200521-code-2010:area-all ;
         cd-dimension:age cd-code:age-all .
}

 

国勢調査の人口に係る統計表で公開している年を調べる

国勢調査の人口に係る統計表(データセットd0003041389)で公開している年を取得するクエリーです

PREFIX qb: <http://purl.org/linked-data/cube#>
PREFIX cd-dimension: <http://data.e-stat.go.jp/lod/ontology/crossDomain/dimension/>
select distinct ?year
where {
      ?s qb:dataSet <http://data.e-stat.go.jp/lod/dataset/g00200521/d0003041389> ;
         cd-dimension:timePeriod ?year .
}

 

データセットd0003041389の構造(測度、次元、属性)を調べる

データセットd0003041389の構造(測度、次元、属性)を取得するクエリーです

PREFIX qb:<http://purl.org/linked-data/cube#>
select distinct ?s
where {
      <http://data.e-stat.go.jp/lod/dataset/g00200521/d0003041389/dsd> qb:component ?y .
      {?y qb:dimension ?s .}
    UNION
      {?y qb:measure ?s .}
    UNION
      {?y qb:attribute ?s .}
}

 

緯度経度を指定して該当する小地域を調べる

東経139.48度、北緯35.92度の地点を含む小地域を取得するクエリーです

PREFIX rdfs:<http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms:<http://purl.org/dc/terms/>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX ogcf: <http://www.opengis.net/def/function/geosparql/>
select ?municipality ?area
where {
      ?s <http://www.opengis.net/ont/geosparql#hasGeometry> ?polygon ;
         rdfs:label ?area ;
         dcterms:isPartOf / rdfs:label ?municipality .
      ?polygon geo:asWKT ?geom .
      FILTER (ogcf:sfContains(?geom, "POINT(139.48 35.92)"^^geo:wktLiteral)) .
      FILTER (LANG(?municipality)='ja') .
}